我想在访问创建检查约束(喷气?)表。
I am trying to create a check constraint on an access (jet?) table.
所以,我打开.mdb文件的访问,进入queries->在设计视图中创建查询, 类型esc键,然后菜单 - >查看 - >查询,最后键入
So, I open the .mdb file with access, go into queries->create query in design view, type esc, then menu->view->query and finally type
创建表X( 一个号码, 确认(a> 20) )
create table X ( a number, check (a > 20) )
但访问认为我有的字段定义语法错误。不过,我不这么认为。因此,我的问题:是否有可能创建一个检查约束访问。如果是这样的:如何
but access thinks that I have a "syntax error in field definition". However, I don't think so. Therefore my question: is it possible to create a check constraint with access. If so: how.
此外,我想创建一个DAO / VBA的限制,而不是在GUI。这可能吗?
Additionally, I'd like to create the constraint with dao/vba, not on the GUI. Is that possible?
最后,在一个稍微有关的注意事项:你怎么输入SQL语句访问。我无法想象,我必须使用queries->设计查看 - >查询 - >查看路线,才能做到这一点。我习惯了Oracle的SQL * Plus的,这是我很喜欢,而且我希望有类似访问的东西为好。
And lastly, on a slightly related note: how do you enter sql statements into access. I can't imagine that I have to use the queries->design view->query->view route in order to do that. I am used to Oracle's SQL*Plus, which I like very much, and I'd hope there's something similar for access as well.
感谢您的任何输入 刘若英
Thanks for any input Rene
下面是一些注意事项。
您可以创建一个传递查询用于Oracle(选择菜单查询>SQL特定>直通)
You can create a Pass-Through query for Oracle (Select menu "Query" > "SQL Specific" > "Pass-Through")
由于Access 2003中,您可以选择的SQL Server兼容语法(ANSI 92)( http://office.microsoft.com/en-us/access/HA010345621033.aspx )
Since Access 2003, you can select SQL Server Compatible Syntax (ANSI 92) (http://office.microsoft.com/en-us/access/HA010345621033.aspx)
使用VBA / DAO验证规则
A validation rule with VBA / DAO
''Reference: Microsoft DAO x.x Object Library
Dim tdf As TableDef
Dim db As Database
Set db = CurrentDb
Set tdf = db.TableDefs("Table1")
tdf.Fields("aDouble").ValidationRule = "<10"
tdf.Fields("aDouble").ValidationText = "Must be less than 10"
约束用ADO / VBA。请参见中级的Microsoft Jet的SQL Access 2000中
''Reference: Microsoft ADO Ext. x.x for DDL and Security
Dim cn As ADODB.Connection 'For action queries
Dim rs As ADODB.Recordset 'For select queries
Dim s As String
Dim RecordsAffected As Long
Set cn = CurrentProject.Connection
''You can store sql in a table
s = DLookup("SQLText", "sysSQL", "ObjectName='q1'")
''Result: CREATE TABLE tblCreditLimit (LIMIT DOUBLE)
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
''You can run queries from VBA
s = "INSERT INTO tblCreditLimit VALUES (100)"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "CREATE TABLE tblCustomers (CustomerID COUNTER, CustomerName Text(50))"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "INSERT INTO tblCustomers VALUES (1, 'ABC Co')"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "ALTER TABLE tblCustomers " _
& "ADD COLUMN CustomerLimit DOUBLE"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
''You can add contraints using ADO like so:
s = "ALTER TABLE tblCustomers " _
& "ADD CONSTRAINT LimitRule " _
& "CHECK (CustomerLimit <= (SELECT LIMIT " _
& "FROM tblCreditLimit))"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "UPDATE tblCustomers " _
& "SET CustomerLimit = 200 " _
& "WHERE CustomerID = 1"
''Error occurs here
cn.Execute s, RecordsAffected
s = "UPDATE tblCustomers " _
& "SET CustomerLimit = 90 " _
& "WHERE CustomerID = 1"
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
''Clean up
''You cannot do this through the database window,
''because of the constraint.
s = "ALTER TABLE tblCustomers DROP CONSTRAINT LimitRule "
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "DROP TABLE tblCustomers "
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected
s = "DROP TABLE tblCreditLimit "
cn.Execute s, RecordsAffected
Debug.Print RecordsAffected